Subject: centrifugal force program
From: Paul
Date: 3/18/2001, 7:58 PM

Vance Jaqua wrote:


Paul
I have to admit that I dropped the ball on checking
your centrifugal force program for the prop - but I
will send you one That I use. It is designed to
evaluate the more difficult composite shell prop with
a non structural ie foam core. but it can be modified
to do solid wood or any other material. You input the
width ans prct thickness at each of 10  equal radius
and it assumes an ellipse for airfoil area
aproximation
and iterates down from the tip giving you force and
stress..



enjoy - Vance


Thanks Vance.

Paul Lamar
 
The AirCraft Rotary Engine NewsLetter.              Powered by Linux.

http://home.earthlink.net/~rotaryeng/            http://www.linux.org

Vance-Prpcstr.bas
1000 REM PRPCSTR PROP CENTRIFUGAL STRESS FOR HOLLOW COMPOSITE WITH FOAM CORE 
1010 PI=3.1416
1090 INPUT" IF PRINT OUT DESIRED INPUT 1 ";PCODE
1100 REM DIM AND CHARACTERISTICS
1126 MODE=2070000! :REM E MODULUS
1128 MODG=MODE/16 :REM TORSIONAL MODULUS
1130 DEN=.07 :REM SHELL MATERIAL DENSITY LB CU IN FIBERGLAS
1132 CDEN=.005 :REM CORE MATERIAL DENSITY HI DENS FOAM
1140 PI=3.1416
1500 REM DIMENSIONS OF PROP
1501 DATA "TYPICAL SPORT PLANE PROP"
1502 DATA 72:REM DIAMETER IN INCHES 
1503 DATA 2700
1505 DIM WD(50),THK(50),RAD(50),WTHK(50)
1510 DATA 2.0,8,.04 :REM WIDTH, PCT THK, WALL THK - DATA FROM TIP IN
1520 DATA 3.0,10,.04
1525 DATA 4.0,12,.04
1530 DATA 5.0,14,.04
1535 DATA 6,15,.05
1540 DATA 7,16,.05
1545 DATA 6,20,.06
1560 DATA 6,22,.06
1562 DATA 5,25,.07
1564 DATA 4,80,.07
1566 DATA 3,100,.07
1600 REM READ DATA
1610 READ CAS$
1620 READ DIA
1622 READ RPM
1630 FOR R=10 TO 0 STEP -1 :REM TO SET DATA FROM TIP IN
1640 READ WD(R),THK(R),WTHK(R)
1650 NEXT R
2000 REM INITIAL CALCS
2200 REM INPUTS PRINT OUT
2201 PRINT " PCNT RAD    WIDTH  PCNT THICK   ANGLE  PITCH "
2202 IF PCODE <1 THEN 2218
2203 LPRINT
2204 LPRINT " PROGRAM PRPSTRSC- COMPUTES PROP STRESS AND TWIST FORCE FROM CENT FORCE"
2205 LPRINT" DATE ";DATE$
2206 LPRINT " CASE ",CAS$
2207 LPRINT " RPM  ",RPM
2208 REM
2209 LPRINT " PCNT RAD    WIDTH  PCNT THICK   ANGLE  WALL THK  "
2218 REM
2220 FOR N= 10 TO 3 STEP-1
2228 IF PCODE < 1 THEN 2290
2230 LPRINT USING"######.###";N*10,WD(N),THK(N),ANG(N),WTHK(N)
2290 REM
2299 NEXT
3000 REM CALCS
3001 PRINT"PCT R RAD-FT WDTH  AREA  ARTOT ARCOR  WT  WTCOR   G'S   FRCE  STRSS  MOMT  "
3002 IF PCODE=1 THEN LPRINT"PCT R RAD-FT WDTH  AREA  ARTOT ARCOR  WT  WTCOR   G'S   FRCE  STRSS  MOMT  "
3005 SECFT=0
3006 NR=10
3010 OMEGA=RPM*2*PI/60
3020 RAD=DIA/(2*12) :REM RADIUS IN FEET
3030 WTT=0
3032 TWATOT=0
3040 ANGO=ANG(10)
3105 FOR RL=1 TO 10
3108 NR=NR-1
3110 RS=INT(NR)
3120 DELW=WD(RS)-WD(RS+1)
3130 WDTH=WD(RS+1)+DELW*(((1*(RS+1))-NR)/1):REM AVERAGE DIM BETWEEN SECTIONS
3140 DELTHK=THK(RS)-THK(RS+1)
3150 THKN=THK(RS+1)+DELTHK*(((1*(RS+1))-NR)/1)
3160 AREAS=.7854*WDTH*(WDTH*THKN/100):REM APPRX AIRFOIL SOLID SECTION AREA
3162 AREAC=.7854*(WDTH-(2*WTHK(RS)))*((WDTH*THKN*.01)-(2*WTHK(RS))) : REM CORE AREA
3164 AREA=AREAS-AREAC :REM APPRX SHELL AREA
3170 SECWTS=AREA*.1*12*RAD*DEN :REM APPRX SHELL SEC WT IN LBS
3171 SECWTC=AREAC*.1*12*RAD*CDEN :REM APPRX CORE SEC WT IN LBS
3172 SECWT=SECWTS+SECWTC
3176 WTT=WTT+SECWT
3180 SECRAD=(NR+.5)*RAD/10:REM SECTION MEAN RADIUS IN FEET
3190 SECG=SECRAD*(OMEGA^2)/32.18 :REM SECTION G'S
3200 SECFRC=(SECWT+SECWTC)*SECG
3210 SECFT=SECFT+SECFRC :REM TOTAL CENT FORCE AT SECTION INTERFACE
3220 STRSS=SECFT/AREA
3800 IF PCODE<1 THEN 3850
3810 LPRINT USING"####";NR,
3820 LPRINT USING"###.##";SECRAD,WDTH,AREA,AREAS,AREAT,SECWT,SECWTC,
3830 LPRINT USING"######";SECG,SECFT,STRSS,MOMTT
3850 REM
3890 PRINT USING"####";NR,
3892 PRINT USING"###.##";SECRAD,WDTH,AREA,AREAS,AREAC,SECWT,SECWTC,
3896 PRINT USING"######";SECG,SECFT,STRSS
3900 NEXT
4000 PRINT" TOTAL WT OF PROP BLADE ";WTT
4010 IF PCODE=1 THEN LPRINT" TOTAL WT OF PROP BLADE ";WTT


v-cent.dat

 PROGRAM PRPSTRSC- COMPUTES PROP STRESS AND TWIST FORCE FROM CENT FORCE
 DATE 03-18-2001
 CASE         TYPICAL SPORT PLANE PROP
 RPM           2700 
 PCNT RAD    WIDTH  PCNT THICK   ANGLE  WALL THK  
   100.000     2.000     8.000     0.000     0.040
    90.000     3.000    10.000     0.000     0.040
    80.000     4.000    12.000     0.000     0.040
    70.000     5.000    14.000     0.000     0.040
    60.000     6.000    15.000     0.000     0.050
    50.000     7.000    16.000     0.000     0.050
    40.000     6.000    20.000     0.000     0.060
    30.000     6.000    22.000     0.000     0.060
 TOTAL WT OF PROP BLADE  2.158426

v-cent2.dat
 PCNT RAD    WIDTH  PCNT THICK   ANGLE  PITCH 
PCT R RAD-FT WDTH  AREA  ARTOT ARCOR  WT  WTCOR   G'S   FRCE  STRSS  MOMT  
   9  2.85  3.00  0.20  0.71  0.50  0.06  0.01  7080   490  2420
   8  2.55  4.00  0.28  1.51  1.23  0.09  0.02  6335  1212  4383
   7  2.25  5.00  0.35  2.75  2.40  0.13  0.04  5590  2191  6206
   6  1.95  6.00  0.53  4.24  3.71  0.20  0.07  4844  3490  6534
   5  1.65  7.00  0.63  6.16  5.53  0.26  0.10  4099  4956  7868
   4  1.35  6.00  0.67  5.65  4.99  0.26  0.09  3354  6122  9175
   3  1.05  6.00  0.68  6.22  5.54  0.27  0.10  2608  7089 10446
   2  0.75  5.00  0.67  4.91  4.24  0.25  0.08  1863  7688 11444
   1  0.45  4.00  0.78 10.05  9.28  0.36  0.17  1118  8280 10667
   0  0.15  3.00  0.64  7.07  6.42  0.28  0.12   373  8427 13079
 TOTAL WT OF PROP BLADE  2.158426