Subject: 2.85:1 verses 2.17:1 psru ratio
From: Paul
Date: 4/1/2001, 3:20 PM

I made a few guesses here as to the static thrust.
One is 500 pounds for Tracy's current prop.
The other is 200 pounds for a really bad high pitch prop
optimized for cruise at 2100 RPM and 180 HP or perhaps Perry 
Mick's ducted fan.

The thrust in theory drops off as speed builds but in actual
fact it probably increases at low speeds  because the blades come out of stall.
In any event I allowed the thrust to degrade at the rate of one
pound per mph. Real results would probably show a shorter takeoff distance
for the 200 pound static thrust case because the thrust would probably
increase rather than decrease in this speed range. 

Here are the takeoff distance results for the two cases and the program 
used to calculate them. The 500 pound static thrust showed a take off
distance of about  500 feet and 65 mph. the 200 pound thrust case showed
about 1500 feet at 65 mph. The wing area used in these examples is a bit too 
small for the RV because obviously the lift coef. is not that high at 65 mph.

1500 feet take off is more like most certified airplanes.

Paul Lamar
 
The AirCraft Rotary Engine NewsLetter.              Powered by Linux.

http://home.earthlink.net/~rotaryeng/            http://www.linux.org


                       AIRCRAFT SIMULATION V71
                     Copyright June 1997 Paul Lamar
                     paul-lamar-la@worldnet.att.net

                                      Gross weight  1500 
             Equivalent square feet with gear down.  4 
 Equivalent flat plate in square feet with gear up.  3 
                   Initial static thrust in pounds.  200 
             Pounds per mph that thrust is reduced. 1.00
                                          Wing span  25 
                                          Wing Area  100 


Time   Net     Accel   Velocity   Distance    Cl     HP Out   Excess   Climb 
Sec    Thrust  FPS^2    MPH        Feet       Req.   Total  HP Avail.  Pot. FPM
  1.58   195    4.17       5         5      285.70       2       2      0
  3.36   190    4.04      10        24       64.21       5       5      0
  5.21   183    3.91      15        56       27.45       7       7      0
  7.12   177    3.77      20       104       15.17       9       9      0
  9.10   169    3.61      25       168        9.63      11      11      0
 11.18   161    3.44      30       251        6.63      13      13      0
 13.36   153    3.27      35       353        4.85      15      14      0
 15.68   144    3.08      40       479        3.70      17      15      0
 18.14   135    2.88      45       631        2.91      18      16      0
 20.78   125    2.67      50       813        2.36      20      17      0
 23.65   115    2.45      55      1032        1.94      21      17      0
 26.80   104    2.21      60      1295        1.63      22      16      0
 30.31    92    1.97      65      1615        1.39      23      16      0



                       AIRCRAFT SIMULATION V71
                     Copyright June 1997 Paul Lamar
                     paul-lamar-la@worldnet.att.net

                                      Gross weight  1500 
             Equivalent square feet with gear down.  4 
 Equivalent flat plate in square feet with gear up.  3 
                   Initial static thrust in pounds.  500 
             Pounds per mph that thrust is reduced. 1.00
                                          Wing span  25 
                                          Wing Area  100 


Time   Net     Accel   Velocity   Distance    Cl     HP Out   Excess   Climb 
Sec    Thrust  FPS^2    MPH        Feet       Req.   Total  HP Avail.  Pot. FPM
  0.64   495   10.57       5         2      285.35       6       6      0
  1.33   490   10.45      10         9       64.72      12      12      0
  2.04   483   10.31      15        22       27.56      19      19      0
  2.76   477   10.17      20        40       15.18      25      25      0
  3.48   469   10.01      25        63        9.65      31      31      0
  4.22   462    9.85      30        93        6.65      37      36      0
  4.97   453    9.67      35       128        4.86      43      42      0
  5.74   444    9.48      40       170        3.70      49      47      0
  6.52   435    9.28      45       218        2.92      54      52      0
  7.32   425    9.07      50       273        2.36      60      56      0
  8.14   415    8.85      55       336        1.94      65      60      0
  8.98   404    8.61      60       406        1.63      70      64      0
  9.84   392    8.37      65       484        1.39      75      67      0


'
' 6/29/97  Version 71
'
'Requires QuickBasic and DOS "MORE".
'Generates ACCEL.DAT ascii file on hard disk in the directory from which
'this program is run.
'All sea level so far.
'
'In general ducted fans are twenty percent less efficient than propellors.
'The same program will work for propellors.
'
DEFDBL A-Z
OPEN "ACCEL5.DAT" FOR OUTPUT AS #1
CLS
FOR x = 1 TO 5: PRINT : NEXT
PRINT #1,
PRINT "                       AIRCRAFT SIMULATION V71"
PRINT #1, "                       AIRCRAFT SIMULATION V71"
PRINT "                     Copyright June 1997 Paul Lamar"
PRINT #1, "                     Copyright June 1997 Paul Lamar"
PRINT "                     paul-lamar-la@worldnet.att.net"
PRINT #1, "                     paul-lamar-la@worldnet.att.net"
PRINT ""
PRINT #1, ""
'
PRINT "             Generates a file called ACCEL.DAT on this sub-directory."
FOR x = 1 TO 5: PRINT : NEXT
INPUT "Press Enter to continue"; z$

CLS

FOR x = 1 TO 5: PRINT : NEXT

INPUT "                    Gross Weight "; Wt
INPUT " Flate plate area with gear down "; FlatPlate
INPUT "   Flate plate area with gear up "; GearUpFP
INPUT "                   Static Thrust "; StaticThrust
INPUT "           Lapse Rate for thrust "; LapseRate
INPUT "                       Wing span "; Span
INPUT "                       Wing area "; WingArea

PRINT
'PRINT #1,
PRINT
'PRINT #1,
'Edit these numbers for your aircraft and propulsion system.

IF Wt = 0 THEN Wt = 1500
'Gross weight.
PRINT "                                      Gross weight "; Wt
PRINT #1, "                                      Gross weight "; Wt

IF FlatePlate = 0 THEN FlatPlate = 4
'Equivalent square feet with gear down.
PRINT "             Equivalent square feet with gear down. "; FlatPlate
PRINT #1, "             Equivalent square feet with gear down. "; FlatPlate

IF GearUpFP = 0 THEN GearUpFP = 2
'Equivalent flat plate in square feet with gear up.
PRINT " Equivalent flat plate in square feet with gear up. "; GearUpFP
PRINT #1, " Equivalent flat plate in square feet with gear up. "; GearUpFP

IF StaticThrust = 0 THEN StaticThrust = 500
'Initial static thrust in pounds.
PRINT "                   Initial static thrust in pounds. "; StaticThrust
PRINT #1, "                   Initial static thrust in pounds. "; StaticThrust

IF LapseRate = 0 THEN LapseRate = 1
'Pounds per mph that thrust is reduced.
PRINT "             Pounds per mph that thrust is reduced. "; USING "#.##"; LapseRate
PRINT #1, "             Pounds per mph that thrust is reduced. "; USING "#.##"; LapseRate

IF Span = 0 THEN Span = 24
PRINT "                                          Wing span "; Span
PRINT #1, "                                          Wing span "; Span

IF WingArea = 0 THEN WingArea = 150
PRINT "                                          Wing Area "; WingArea
PRINT #1, "                                          Wing Area "; WingArea

FOR x = 1 TO 5: PRINT : NEXT
PRINT #1,
PRINT #1,

INPUT "Press Enter to continue"; z$

'Don't change any of this.
pi = 3.1416
DeltaTime = .01        'Time increment in seconds. Smaller is better.
Velocity = .01         'Initial velocity in  FPS. Do not change.
LiftOffCoef = 1.2      'Cl at which rotation is initiated
ClimbCoef = 1.19       'Cl at which climb can be initiated.
Flag = 1               'Used by program. Do not change

Thrust = StaticThrust  'Initialise thrust to static thrust.
AverageCord = WingArea / Span
Aspect = Span / AverageCord        'Aspect ratio

CLS


PRINT #1, "Time   Net     Accel   Velocity   Distance    Cl     HP Out   Excess   Climb "
PRINT #1, "Sec    Thrust  FPS^2    MPH        Feet       Req.   Total  HP Avail.  Pot. FPM"

'Cl Req. is the lift coefficient required to = the weight of the aircraft.
'HP Out Total    is the actual HP out of the tail pipe in terms of Lb Ft/Sec.
'HP Ex. Avail.   is the excess HP available for climbing.
'Climb Pot. FPM  is the rate of climb available at that speed and time.

FOR Time1 = DeltaTime TO 2000 STEP DeltaTime      'seconds

MPH = Velocity * .682
IF MPH > 75 THEN FlatPlate = GearUpFP       'Gear up point.
IF MPH \ 5 = Flag THEN GOSUB TimetoPrint    'Print the output
DynPress = (MPH ^ 2 * .0026)                'Standard day.
Cl = Wt / (DynPress * WingArea)             'Cl required to = weight.
IF Cl > 999 THEN Cl = 999 ELSE Cl = Cl      'Cosmetic fix only.
IF Cl < LiftOffCoef THEN GOSUB CalcDrag     'After rotate calc induced drag.
IF Cl < ClimbCoef THEN GOSUB CalcClimb      'Calc climb potential.

Thrust = StaticThrust - (MPH * LapseRate)
NetThrust = Thrust - (DynPress * FlatPlate) - InducedDrag

Accel = (NetThrust / Wt) * 32                'In FPS^2
IF Accel < .005 THEN GOTO EndIt              'Top speed so exit the loop.
Velocity = Velocity + Accel * DeltaTime
Distance = Distance + (Velocity * DeltaTime)

HP = (Velocity * NetThrust) / 550         'Net HP after drag avail for climb.
THP = Thrust * Velocity / 550             'Thrust HP out the tail pipe.

NEXT Time1
EndIt:
PRINT #1,
CLOSE
CLS


SHELL "MORE < ACCEL5.DAT"      'Look at the data file on the disk.
FOR x = 1 TO 10: PRINT : NEXT
PRINT "                         Have a nice day!"
PRINT
PRINT "                     paul-lamar-la@worldnet.att.net"
SYSTEM

CalcDrag:                      'Calculate the induced drag component.
InducedDrag = (((Cl ^ 2 / (pi * Aspect)) * WingArea) * DynPress)
RETURN

CalcClimb:                     'Calculate the climb potential.
FootLbMin = HP * 33000
Climb = FootLbMin / Wt
RETURN

TimetoPrint:
PRINT Flag;
'READ Thrust                      'Not used unless empirical data is avail.
Flag = Flag + 1
PRINT #1, USING "###.##"; Time1;
PRINT #1, USING "   ###"; NetThrust;
PRINT #1, USING "   ##.##"; Accel;
PRINT #1, USING "     ###"; MPH;
PRINT #1, USING "    ######"; Distance;
PRINT #1, USING "    #####.##"; Cl;
PRINT #1, USING "   #####"; THP;
PRINT #1, USING "   #####"; HP;
PRINT #1, USING "   ####"; Climb
RETURN

'Not used when lapse rate is available.

'   Edit this for characteristics of the propulsion system.
'   Fixed pitch, variable pitch, twist, ducted fan, etc..
'     Thrust data in pounds at 5 MPH increments.
'MPH   5   10   15   20   25   30   35   40   45   50
DATA  100, 101, 102, 103, 104, 105, 106, 107, 108, 109

'MPH  55  60   65   70   75   80   85   90   95   100
DATA 110, 115, 120, 125, 130, 135, 140, 145, 150, 155

'MPH 105  110  115  120  125  130  135  140  145  150
DATA 160, 165, 170, 175, 180, 190, 195, 200, 205, 210

'MPH 155  160  165  170  175  180  185  190  195  200
DATA 215, 220, 220, 220, 220, 220, 220, 220, 220, 220

'MPH 205  210  215  220  225  230  235  240  245  250
DATA 220, 220, 220, 220, 220, 220, 220, 220, 220, 220

'MPH 255  260  265  270  275  280  285  290 295  300
DATA 220, 220, 220, 220, 220, 200, 100, 50,  25,  0