Vance,
Thanks for taking the time to run this thru your program. I plan to turn my 13b up to 7400 RPM which equals 2,597 prop RPM. I have the prop program spreadsheet by John Ronze (sp?? - the guy of Longez canard and RV-9 wing fame) that I have used to run the numbers but that data is at work and I do not have the data (or the program) before me or I would compare the data points. I think that his program also used the Clark Y airfoil. I was also interested in what airfoil would really be best suited to this flight envelope - is the Ckark Y really still the best?
Ken if the one I just sent does not work try this one.
I think the first one was my attempt to convert Vance's GW Basic
program to QB.
Paul Lamar
The AirCraft Rotary Engine NewsLetter. Powered by Linux.
ACRE NL web site.
http://home.earthlink.net/~rotaryeng/ http://www.linux.org
CLS
1000 REM PROGRAM PRPSIZ
1001 KEY OFF
1005 REM UPDATED APR 12 86 - EFF CORR
1010 REM COMBINED PROGRAM FOR BOTH TOP SPEED AND CRUISE CASES
1020 REM PROPELLOR DESIGN AID
1030 REM
1040 PRINT "INPUT 1 IF HARD COPY DESIRED "
1050 INPUT PCD
1060 REM
1070 INPUT "NAME OF CASE ", CS$
1090 INPUT "RATED BHP, RPM, SEA LEVEL TOP SPEED ", HP, RP, TS
1110 PI = 3.1417
1120 REM ASSUMED CLARK Y AIRFOIL AT 0 DEGREE BASED ON FLAT BOTTOM SURFACE
1125 AT = 0
1130 ANGAT = AT * PI / 180
1140 CL = .4
1150 CD = .02
1160 AIRDEN = .002377
PRINT RP
const1 = 800
const2 = 900
1170 DW = (const1 * 12 * 60) / (PI * RP)
1180 DM = (const2 * 12 * 60) / (PI * RP)
1190 PRINT " TIP SPEED RECOMMENDED DIA "
1200 PRINT " WOOD PROP "; DW; " INCHES"
1210 PRINT " METAL PROP "; DM; " INCHES"
1220 PRINT
1230 INPUT "MAXIMUM DIA DESIRED, AND MAX WIDTH ", DI, WMAX
1250 REM ************* FIRST TIME WITH ASSUMED EFF *****************
1260 PREFF = .7
1265 FOR TPS = 1 TO 3
1270 PRINT "PROP EFFICIENCY ASSUMED AT "; (100 * PREFF); " percent"
1310 TH = HP * PREFF
1320 PRINT "THRUST HP "; TH
1330 TF = TS * 88 / 60
1340 F = TH * 550 / TF
1350 PRINT "TOP SPEED THRUST "; F; " LBS"
1360 REM DISK AREAS
1370 DA = .7854 * ((DI / 12) ^ 2): REM DISK AREA IN SQ FT
1380 REM DELTA V BASED ON ONLY 90 PERCENT EFFECTIVE DISK AREA
1390 MF = TF * DA * .9 * AIRDEN: REM MASS FLOW BASED ON FORWARD SPEED
1400 DV = F / MF
1410 PRINT "DELTA V "; DV; " FT/SEC"
1412 AXV = TF + DV
1414 ROTV = RP * DI * PI / (12 * 60)
1416 TIPV = SQR((AXV ^ 2) + (ROTV ^ 2))
1417 IF TPS < 2.5 THEN 1465
1418 PRINT "TIP SPEED "; TIPV
1420 REM ---------------------------------------------------
1430 PRINT
1440 PRINT " ZONE ZONE ANGLE WIDTH ZONE ZONE ZONE ZONE ZONE"
1450 PRINT " AREA IN. HP THRST THR/HP PITCH VEL "
1460 PRINT
1465 REM INITIALIZE VALUES
1470 PWRT = 0
1480 THRTOT = 0
1490 IF PCD <> 1 THEN 1710
1492 IF TPS < 2.5 THEN 1710
1500 LPRINT " PROGRAM PRPSIZ - INITIAL PROP SIZ REC."
1502 LPRINT " PITCH BASED ON CLARK Y TYPE FOIL MEASURED ON BOTTOM SURFACE"
1503 LPRINT " BLADE WIDTH BASED ON TWO BLADE PROP - ADJUST FOR BLADE NUMBER"
1504 LPRINT CS$
1505 LPRINT
1550 LPRINT "INPUT VALUES"
1555 LPRINT
1560 LPRINT " ENGINE RATED POWER "; HP; " BHP - AT "; RP; " RPM"
1570 LPRINT " TOP SPEED AT THAT POWER "; TS; " MPH"
1575 LPRINT " SELECTED PROP DIA "; DI; " INCHES"
1576 LPRINT " ESTIMATED PROP EFFICIENCY "; (100 * PREFF); " PERCENT"
1580 LPRINT " AIR FLOW DELTA - V THROUGH DISK "; DV; " FT/SEC"
1582 LPRINT " TIP SPEED "; TIPV; " FPS"
1590 LPRINT " ANGLE OF ATTACK RELATED TO VELO THROUGH DISK = "; AT; " DEGREES"
1600 LPRINT ""
1680 LPRINT " ZONE ZONE ANGLE WIDTH ZONE ZONE ZONE ZONE"
1690 LPRINT " AREA IN. HP THRUST PITCH VEL "
1700 LPRINT
1710 REM
1720 REM LOOP FOR RADIUS ZONES FROM .3 TO .9 (.2 WIDE)
1730 FOR L = 3 TO 9 STEP 2
1740 DAREA(L) = .7854 * ((DI * .1 * (L + 1)) ^ 2 - (DI * .1 * (L - 1)) ^ 2)
1750 DAREA(L) = DAREA(L) / 144
1760 REM DELTA V
1770 REM PITCH LINE VEL
1780 PVEL(L) = RP * DI * .1 * L * PI / (60 * 12)
1790 REM ANGLE
1800 ANG(L) = ATN((DV + TF) / PVEL(L))
1810 ANG(L) = ANG(L) + ANGAT
1820 ANGD(L) = ANG(L) * 180 / PI
1830 REM PITCH
1840 P(L) = .1 * DI * L * PI * TAN(ANG(L))
1850 VQ(L) = PVEL(L) / COS(ANG(L))
1860 Q(L) = AIRDEN * (VQ(L) ^ 2) / 2
1870 FZ(L) = Q(L) * ((CL * COS(ANG(L))) - (CD * SIN(ANG(L))))
1880 DZ(L) = Q(L) * ((CD * COS(ANG(L))) + (CL * SIN(ANG(L))))
1890 WDTH(L) = F * DAREA(L) * 144 / (.9 * DA * FZ(L) * .2 * DI)
1900 IF WDTH(L) > WMAX THEN WDTH(L) = WMAX
1910 REM POWER REQUIRED
hpconst = 550
1920 PWR(L) = DZ(L) * PVEL(L) * WDTH(L) * .2 * DI / (144 * hpconst)
1930 THRST(L) = FZ(L) * WDTH(L) * .2 * DI / 144
1932 TPH = THRST(L) / PWR(L)
1940 THRTOT = THRTOT + THRST(L)
1950 PWRT = PWRT + PWR(L)
1952 IF TPS < 2.5 THEN 1970
1955 PRINT USING "######"; L;
1960 PRINT USING "####.###"; DAREA(L); ANGD(L); WDTH(L); PWR(L); THRST(L); TPH; P(L); VQ(L)
1970 IF PCD <> 1 THEN 1979
1972 IF TPS < 2.5 THEN 1979
1974 LPRINT USING "######"; L;
1975 LPRINT USING "#####.###"; DAREA(L); ANGD(L); WDTH(L); PWR(L); THRST(L); P(L); VQ(L)
1979 REM
1980 NEXT
1990 REM
1992 IF TPS < 2.5 THEN 2030
2000 PRINT "PITCH "; P(7); "INCHES"
2010 PRINT "TOTAL POWER "; PWRT
2020 PRINT "TOTAL THRUST "; THRTOT; " LBS"
2030 PREFT = THRTOT * TF / (PWRT * 550)
2040 PRINT "PROP EFFICIENCY "; PREFT
2050 IF PCD <> 1 THEN 2120
2052 IF TPS < 2.5 THEN 2120
2060 LPRINT
2070 LPRINT "PITCH "; P(7); " INCHES"
2080 LPRINT "TOTAL POWER "; PWRT
2090 LPRINT "TOTAL THRUST "; THRTOT; " LBS"
2110 LPRINT "PROP EFFICIENCY "; PREFT
2111 LPRINT
2112 LPRINT
2120 REM
2314 REM ************ RESET EFF TO FIRST COMPUTED VALUE *********
2315 PREFF = PREFT
2316 NEXT TPS
2320 REM
2330 PRINT
8000 REM **************************************************
8010 REM CRUISE PROP SIZING
8060 PRINT
8070 PRINT
8080 PRINTT = 0
8220 CRHP = .75 * HP
8230 PRINT "CRUISE HP ASSUMED 75% OF RATED "; CRHP
8240 RP = .9 * RP
8250 PRINT "CRUISE RPM ASSUMED 90% OF RATED "; RP
8255 CS = .9 * TS
8260 PRINT " CRUISE SPEED ASSUMED AT 90 % OF TOP SPEED "; CS
8270 PRINT " INPUT PROP EFF FROM PREV CALC = "; (100 * PREFF); " PERCENT"
8280 TH = CRHP * PREFF
8290 PRINT "THRUST HP "; TH
8300 CF = CS * 88 / 60
8310 F = TH * 550 / CF
8320 PRINT "CRUISE THRUST "; F; " LBS"
8330 REM DISK AREAS
8340 DA = .7854 * ((DI / 12) ^ 2): REM DISK AREA IN SQ FT
8350 REM DELTA V BASED ON ONLY 90 PERCENT EFFECTIVE DISK AREA
8360 MF = CF * DA * .9 * AIRDEN: REM MASS FLOW BASED ON FORWARD SPEED
8370 DV = F / MF
8380 PRINT "DELTA V "; DV; " FT/SEC"
8390 REM ---------------------------------------------------
8400 PRINT
8410 PRINT " ZONE ZONE ANGLE WIDTH ZONE ZONE ZONE ZONE ZONE"
8420 PRINT " AREA IN. HP THRUST THR/HP PITCH VEL "
8430 PRINT
8440 REM REZERO VALUES FOR LOOP
8450 PWRT = 0
8460 THRTOT = 0
8470 IF PCD <> 1 THEN 8590
8480 LPRINT "INPUT VALUES"
8490 LPRINT
8510 LPRINT " ENGINE CRUISE POWER "; CRHP; " BHP - AT "; RP; " RPM"
8520 LPRINT " CRUISE SPEED AT THAT POWER "; CS; " MPH"
8530 LPRINT " SELECTED PROP DIA "; DI; " INCHES"
8535 LPRINT " PROP EFF FROM PREV CALC = "; (100 * PREFF); " PERCENT"
8540 LPRINT " AIR FLOW DELTA - V THROUGH DISK "; DV; " FT/SEC"
8550 LPRINT
8560 LPRINT " ZONE ZONE ANGLE WIDTH ZONE ZONE ZONE ZONE"
8570 LPRINT " AREA IN. HP THRUST PITCH VEL "
8580 LPRINT
8590 REM
8600 REM LOOP FOR RADIUS ZONES FROM .3 TO .9 (.2 WIDE)
8610 FOR L = 3 TO 9 STEP 2
8620 DAREA(L) = .7854 * ((DI * .1 * (L + 1)) ^ 2 - (DI * .1 * (L - 1)) ^ 2)
8630 DAREA(L) = DAREA(L) / 144
8640 REM DELTA V
8650 REM PITCH LINE VEL
8660 PVEL(L) = RP * DI * .1 * L * PI / (60 * 12)
8670 REM ANGLE
8680 ANG(L) = ATN((DV + CF) / PVEL(L))
8690 ANG(L) = ANG(L) + ANGAT
8700 ANGD(L) = ANG(L) * 180 / PI
8710 REM PITCH
8720 P(L) = .1 * DI * L * PI * TAN(ANG(L))
8730 VQ(L) = PVEL(L) / COS(ANG(L))
8740 Q(L) = AIRDEN * (VQ(L) ^ 2) / 2
8750 FZ(L) = Q(L) * ((CL * COS(ANG(L))) - (CD * SIN(ANG(L))))
8760 DZ(L) = Q(L) * ((CD * COS(ANG(L))) + (CL * SIN(ANG(L))))
8770 WDTH(L) = F * DAREA(L) * 144 / (.95 * DA * FZ(L) * .2 * DI)
8780 IF WDTH(L) > WMAX THEN WDTH(L) = WMAX
8790 REM POWER REQUIRED
8800 PWR(L) = DZ(L) * PVEL(L) * WDTH(L) * .2 * DI / (144 * hpconst)
8810 THRST(L) = FZ(L) * WDTH(L) * .2 * DI / 144
8820 THRTOT = THRTOT + THRST(L)
8830 PWRT = PWRT + PWR(L)
8840 PRINT USING "######"; L;
8850 PRINT USING "#####.###"; DAREA(L); ANGD(L); WDTH(L); PWR(L); THRST(L); P(L); VQ(L)
8860 IF PCD <> 1 THEN 8890
8870 LPRINT USING "######"; L;
8880 LPRINT USING "#####.###"; DAREA(L); ANGD(L); WDTH(L); PWR(L); THRST(L); P(L); VQ(L)
8890 REM
8900 NEXT
8910 REM
8920 PRINT "PITCH "; P(7); "INCHES"
8930 PRINT "TOTAL POWER "; PWRT
8940 PRINT "TOTAL THRUST "; THRTOT; " LBS"
8950 PREFT = THRTOT * CF / (PWRT * 550)
8960 PRINT "PROP EFFICIENCY "; PREFT
8970 IF PCD <> 1 THEN 8982
8972 LPRINT
8974 LPRINT "PITCH "; P(7); " INCHES"
8976 LPRINT "TOTAL POWER "; PWRT
8978 LPRINT "TOTAL THRUST "; THRTOT; " LBS"
8980 LPRINT "PROP EFFICIENCY "; PREFT
8982 REM
8984 END