These are my wild ass guess of the HP consumed by a prop as
a
function of
the RPM looks like. They arer in no way quantitative at this
point. It
could
be some other math function and may in fact not be so simple.
Due to the fact that tips of the prop approach supersonic
velocity
and
a consequently steep drag rise the shapes of these curves
could be
far
different.
I am hoping Vance can come up with some prop HP consumption
figures
based
on
his computer simulations.
Paul Lamar
Paul and others - I think this is somwhat like what you are
seeking.
The
HP
and
torque curves are plotted with EXCEL and are against a 2.85
reduction
(torque
is foot lbs at the engine and HP is at the prop. The prop load
curves
are
for
a simulated 73 in dia with 115 in pitch for a 240 mph plane,
blade
area
is
set to absorb appropriate power at that speed. the static and
130
mph
(climb)
power curves run in a terrible pit of low HP this 2.85 reduction
appears
not good on a fast plane static is almost hopelessly stalled and
power
has
not
really come on for climb. Variable pitch is really needed to
make
this a
happy
set up. - Vance
We are on to something here Vance. What does it look like set to
230 MPH and 68 inches?
3 blades perhaps?
What flat plate drag does this work out to?
Great work. Exactly what we are looking for. Thanks.
Paul Lamar
Paul - I have a problem understanding why you want a smaller prop
dia.
With
the
2.85 reduction and the curves you have provided, the tip speeds are
very
modest.
Smaller diameter is going to have a perf penalty everywhere, and
most
heavily
at static and climb. These curves show a dreadful power cave in
right at
those
operating points. This would almost force a controllable prop with
all
it's
cost, weight and complexity.
The new curve is a bit cleaner, and shows that the smaller prop is a
bit
easier to spin at static, but the crummy disk loading provides less
thrust
even tho the engine is cranking a bit more HP. At design point the
two
props are a wide single curve - noise would be down, but I have
trouble
seeing any other good side to this.
240 mph would be about 2.5 eff flat plate which would be a very
clean
Cruiser, or an average composite retract of similar size. The number
of
blades
has virtually no impact on preformance - the wake losses wipe out
any
gain
from higher aspect ratio blades. - Vance
Thanks again for this work Vance. As I suspected the climb and the top
speed curves move closer together.
Well that is what we want to find out. It might be cheaper to build
a variable runner length manifold than to buy a constant speed prop
since
gear boxes
with governor drives are either very expensive or unavailable.
I would not exactly call 150 HP at static and about 175 HP for climb a
"dreadful power cave in" for what amounts to a top speed prop.
Particularly on such light weight airplanes like the RV4, RV6, RV3,
Tailwind, etc.,
etc. Most two place experimentals don't need all that much climb HP.
The
four place
airplanes really need a constant speed prop to get max performance.
If climb is a priority one can always buy a lower pitch climb prop of
course.
Broadening the HP curve can be simply done on the side port engines at
the
expense
of peak power by using longer runners for the small center ports.
We are rapidly expanding our options here with all this manifold R&D.
So far rotary engine manifold design has been hit or miss with people
winding up
with runners that are too long or too small for top speed. This is
partially due
to the limited amount of room on the top of the engine and dealing
with
the oil filler and dip stick that just happen to be were the plenum
needs
to go.
Most people claim better climb performance and a top speed hit with
three
blade
props.
BTW do you have the formula you use for calculations and plotting
these
HP curves as a function of prop RPM? Also have you added altitude
as a prop design variable to your program?
Paul Lamar
The program that is used utilizes an iterative matching of results
between
a momentum disc assumption and a strip element calculation that uses
airfoil data and blade area against flow velocity through the disc.
Hundreds
of loops per point. It is written in BASIC, and can be made available
tho
not completely intuitave to run. It can be run for any reasonable
altitude.
It does not recognize any sonic effects. Results are printed in tabular
form, and at present I transfer the points manually to EXCEL for plots.
Vance
I can handle the source code. QB or VB? What rational does Paul Lipps use
for his plan form? My guess is constant HP per blade element.
Paul Lamar
here is the BASIC program for prop perf prediction, it tries to find a dos
list device for printout. use only the short printout or you will drown in
paper. This will work down to static pretty well.
Paul Lipps likes to load the inner circle of the disc, and constant hp per
strip would probably do that and might look like that. I like to strive
for a constant hp per squr ft till I get into .2 radius and ignore anything
that
far in - most of that is spinner anyway I like to shape the tip to slightly
reduce tip loss just like a wing - but I do not go with reduced angle of
attack out there, - Vance
I think I have that version unless you made revisions in the last few years.
Here also is some output data you sent awhile back.
BTW if anybody needs QB let me know. Runs fine on Windows XP in command mode.
Paul Lamar
The Rotary Engine NewsLetter. Powered by Linux.
ACRE NL web site. http://home.earthlink.net/~rotaryeng/
Copyright 1998-2004 All world wide rights reserved.
1000 REM PRPLRITF QUICK BASIC VERSION PRPLR PROG FOR PWR PRED
1001 REM NO ENGINE POWER CURVES USED JUST REQD POWER PRINTED OUT
1003 REM UPDATED FOR ALTITUDE INPUT
1010 REM PROGRAM FOR STATIC AND MOVING THRUST
1020 DIM BANG(10), WDTH(10)
1030 DIM ANG(30), CL(30), CD(30)
1050 DIM SPD(20), RPM(20)
1060 DIM HPD(80): REM USED IN POWER SUBROUTINES
2000 REM FIXED DATA
2020 PI = 3.1417
2030 G = 32.18
3010 REM ------------------ INPUT DATA -----------------------
3020 INPUT "INPUT NAME OF CASE ", CASE$
3021 AIRDSL = 2.37689E-03
3022 INPUT "INPUT DESIRED ALTITUDE IN FEET "; ALTF
3024 AIRDEN = 2.37689E-03 * ((1 - 6.8753E-06 * ALTF) ^ 4.2651)
3030 INPUT "INPUT CONDITIONS PROP DIA, PITCH (INCHES) ", DIA, PITCH
3040 INPUT "INPUT BLADE WIDTH AT .9, .7, .5, .3 RADIUS "; WDTH(9), WDTH(7), WDTH(5), WDTH(3)
3045 INPUT "INPUT BLADE ANGLE AT .9, .7, .5, .3 RAD. OR ZEROS FOR TRUE HELICAL PITCH "; BANG(9), BANG(7), BANG(5), BANG(3)
3050 INPUT "INPUT NUMBER OF DESIRED PLANE SPEEDS "; NSPD
3060 FOR NS = 1 TO NSPD
3062 INPUT "INPUT PLANE SPEED MPH "; SPD(NS)
3066 INPUT "INPUT STARTING PROP RPM AND DESIRED INCREMENTS "; RPM(NS),DELRPM
3069 NEXT NS
3088 INPUT "INPUT FUSELAGE CROSS SECT AREA SQFT, DRAG COEFF (.2 AVG) "; AFUS, CDFUS
3090 INPUT "INPUT 1 FOR SHORT PRINTOUT 2 FOR LONG "; PCODE
3092 REM --------------------- HARD COPY OF INPUT DATA -------
3100 IF PCODE < .9 THEN 3200
3110 LPRINT "PROGRAM PRPLRITF - FOR THRUST AND POWER AT DESIGNATED SPEEDS AND RPM"
3120 LPRINT
3130 LPRINT DATE$, TIME$
3140 LPRINT
3150 LPRINT "CASE "; CASE$; " - ALTITUDE "; ALTF; " FT - DENSITY "; AIRDEN
3169 LPRINT " PROP DIA "; DIA; "IN PITCH "; PITCH; "IN"
3170 LPRINT " RPM "; RPM
3180 LPRINT " BLADE WIDTH @ .9R "; WDTH(9); " .7R "; WDTH(7); " .5R "; WDTH(5);
3185 LPRINT " .3R "; WDTH(3)
3186 LPRINT " FUSELAGE AREA "; AFUS; " DRAG COEFF "; CDFUS
3190 LPRINT
3194 LPRINT
3200 REM --------------- DATA FOR AIR FOIL --------------------------------
3210 REM CLARK Y WITH 6 ASPECT RATIO
3220 REM ANG ATT, LIFT COEFF, DRAG COEFF
3222 DATA -35,-1.25,.4
3224 DATA -30,-1.55,.3
3226 DATA -25,-1.4,.15
3228 DATA -20,-1.12, .1
3230 DATA -15, -.74, .04
3240 DATA -10, -.38, .02
3250 DATA -5, 0, .01
3260 DATA 0, .38, .02
3270 DATA 5, .74, .04
3280 DATA 10, 1.12, .1
3290 DATA 15, 1.4, .15
3300 DATA 20, 1.55, .3
3310 DATA 25, 1.25, .4
3320 DATA 30, 1.0, .6
3330 DATA 35, .8, .8
3340 DATA 40, .6, 1
3341 DATA 45, .55, 1.2
3342 DATA 50, .5, 1.5
3343 DATA 55, .45, 1.7
3344 DATA 60, .4, 2
3350 REM LOAD AIRFOIL DATA
3360 FOR N = 1 TO 20
3370 READ ANG(N), CL(N), CD(N)
3380 NEXT N
4000 REM************* SPEED LOOP ***********************
4010 FOR NS = 1 TO NSPD
4015 PVEL = SPD(NS)
4020 PLANEV = PVEL * 88 / 60
4022 IF PCODE = 1 THEN LPRINT " MPH RPM THR THR BHP DELTA EFF JET SYS NET(-FUS DRG) ANG ATT"
4023 IF PCODE = 1 THEN LPRINT " LBS HP REQ V(FPS) PRP EFF EFF THR THRHP @.9R .7R .3R"
4024 IF PCODE = 1 THEN LPRINT
4030 REM***********************************************************
4031 REM DELRPM FROM INPUT
4032 RPM = RPM(NS) - DELRPM
4033 FOR NR = 1 TO 10
4034 RPM = RPM + DELRPM
4036 REM ******************* RPM LOOP **************************
4040 REM ZERO OUT VALUES FOR LOOP
4050 HPTOT = 0
4060 THRTOT = 0
4070 JETTOT = 0
4080 REM COMPUTATIONS
4090 REM LOOP FOR RADIUS POINTS
4110 IF PCODE < 2 THEN 4150
4120 LPRINT "RADIUS "; "WIDTH "; "ANGLE "; "HP ZONE "; "LIFT THRST ";
4130 LPRINT "ANG ATT "; "PITCH VEL"
4140 LPRINT
4150 REM
4155 RADT = 0
4156 DELVT = 0
4159 REM ************************************************************
4160 FOR RAD = .3 TO .9 STEP .2
4165 LRAD = INT(.1 + (RAD * 10))
4170 RZMIN = RAD - .1
4180 RZMAX = RAD + .1
4190 WIDZON = WDTH(LRAD)
4210 PLVEL = RPM * DIA * RAD * PI / (12 * 60): REM PITCH LINE VEL - FPS
4220 BLANGT = PITCH / (RAD * DIA * PI)
4225 BLANG = BANG(LRAD) * PI / 180: REM BLADE ANGLE IN RADIANS FROM INPUT LINE
4230 IF BANG(LRAD) < 1 THEN BLANG = ATN(BLANGT): REM BLADE ANGLE IF INPUT ZEROS
4240 BLANGD = BLANG * 180 / PI: REM BLADE ANGLE IN DEGREES
4250 DISCAR = (((RZMAX * DIA) ^ 2) - ((RZMIN * DIA) ^ 2)) * .7854 / 144
4260 BLDAR = DIA * (RZMAX - RZMIN) * WIDZON / 144
4270 REM AREAS IN SQUARE FEET -BLADE AREA FOR TWO BLADES
4280 TOUT = 0
4290 REM
4300 INVFAC = 1!
4310 REM INVFAC IS THE FACTOR FOR INLET VEL RELATIVE TO MOM VEL
4320 REM
4340 REM ---------LOOP FOR DELTA V ----------------------
4350 FOR DELV = 10 TO 190 STEP 10
4360 AIRVEL = PLANEV + (INVFAC * DELV)
4370 AIRANG = ATN(AIRVEL / PLVEL)
4380 ANGAT = BLANG - AIRANG
4390 ANGATD = ANGAT * 180 / PI
4400 NAFD = INT((ANGATD / 5) + 8)
4410 AIRWF = AIRVEL * AIRDEN * DISCAR
4420 MOMF = AIRWF * DELV
4430 DELCL = CL(NAFD + 1) - CL(NAFD)
4440 DELANG = ANGATD - ANG(NAFD)
4450 CLZON = CL(NAFD) + (DELANG * DELCL / 5)
4460 LFTVEL = PLVEL / COS(AIRANG)
4470 LFTQ = AIRDEN * .5 * (LFTVEL ^ 2)
4480 LIFT = CLZON * LFTQ * BLDAR
4490 DELCD = CD(NAFD + 1) - CD(NAFD)
4500 CDZON = CD(NAFD) + (DELANG * DELCD / 5)
4510 DRAG = CDZON * LFTQ * BLDAR
4520 LIFTHR = LIFT * COS(AIRANG) - DRAG * SIN(AIRANG)
4530 TORDRG = DRAG * COS(AIRANG) + LIFT * SIN(AIRANG)
4540 HPZON = TORDRG * PLVEL / 550
4550 DVHEAD = (DELV ^ 2) / (2 * G)
4560 REM JET HP
4570 EXVEL = PLANEV + DELV
4580 JETHP = LIFTHR * EXVEL / 550
4640 IF MOMF > LIFTHR THEN DELV = DELV - 1: TOUT = 1: GOTO 4360
4650 IF TOUT > 0 THEN 4670
4660 NEXT DELV
4665 REM ---------------- END OF DELT V LOOP ---------------
4666 REM OUT OF LOOP
4670 REM OUT OF LOOP
4671 IF RAD = .9 THEN AAT9 = ANGATD
4672 IF RAD = .7 THEN AAT7 = ANGATD
4673 IF RAD = .5 THEN AAT5 = ANGATD
4680 PRINT USING "#####.##"; RAD; WIDZON; BLANGD; HPZON; LIFTHR;
4690 PRINT USING "#####.##"; ANGATD; PLVEL; DELV
4700 IF PCODE < 1.5 THEN 4740
4710 LPRINT USING "#####.##"; RAD; WIDZON; BLANGD; HPZON; LIFTHR;
4720 LPRINT USING "#####.##"; ANGATD; PLVEL
4740 REM
4750 HPTOT = HPTOT + HPZON
4760 THRTOT = THRTOT + LIFTHR
4770 JETTOT = JETTOT + JETHP
4780 REM DEVICE FOR WEIGHTED AVERAGE OF DELTA V
4781 DELVT = DELVT + RAD * DELV
4782 RADT = RADT + RAD
4790 NEXT RAD
4860 REM ************ CORRECTION FOR ADDED FUSELAGE DRAG *************
4862 DELVA = DELVT / RADT
4864 EXVELA = PLANEV + DELVA
4870 FUSQ = AIRDEN * .5 * (PLANEV ^ 2)
4872 FUSQP = AIRDEN * .5 * (EXVELA ^ 2): REM FUSELAGE Q IN PROPWASH
4874 FUSDRG = FUSQ * AFUS * CDFUS
4876 FUSDRGP = FUSQP * AFUS * CDFUS: REM FUSELAGE DRAG IN PROPWASH
4878 DELDRG = FUSDRGP - FUSDRG
4879 PRINT "FUS DRAG "; FUSDRG; " DRAG IN PROPWASH "; FUSDRGP
5000 REM -------- SUMMATIONS ---------------------------
5010 THRHP = THRTOT * PLANEV / 550
5015 THRNET = THRTOT - DELDRG
5020 EFF = THRHP / HPTOT
5030 JEFF = JETTOT / HPTOT
5040 TVEL = (((PLVEL / .9) ^ 2) + (AIRVEL ^ 2)) ^ .5
5042 NTHRHP = THRNET * PLANEV / 550: REM NET THUST HP
5043 SEFF = NTHRHP / HPTOT: REM SYSTEM PROPULSIVE EFF WITH ADDED FUS DRAG
5062 PRINT "PLANE VEL "; PVEL; " RPM "; RPM; " PITCH "; PITCH
5065 PRINT "TOTAL THRUST "; THRTOT, "TOTAL HP "; HPTOT
5070 PRINT "THRUST HP "; THRHP
5072 PRINT "FUSELAGE ADDED DRAG "; DELDRG; " THRUST MINUS THIS LOSS "; THRNET; " LBS"
5074 IF PCODE = 1 THEN LPRINT USING "#####"; PVEL, RPM,
5075 IF PCODE = 1 THEN LPRINT USING "#####"; THRTOT, THRHP, HPTOT, DELVT,
5076 IF PCODE = 1 THEN LPRINT USING "##.###"; EFF, JEFF, SEFF,
5077 IF PCODE = 1 THEN LPRINT USING "######"; THRNET, NTHRHP,
5079 IF PCODE = 1 THEN LPRINT USING "####.#"; AAT9, AAT7, AAT5
5080 IF PCODE < 1.5 THEN 5170
5085 LPRINT
5090 LPRINT "PLANE SPEED "; PVEL; "MPH RPM "; RPM
5100 LPRINT " PITCH AT THIS POINT "; PITCH; " INCHES"
5110 LPRINT "APPROX AIR VEL OVER TIP "; TVEL; " FT/SEC"
5120 LPRINT "TOTAL THRUST "; THRTOT; " HORSEPOWER REQUIRED "; HPTOT
5130 LPRINT "THRUST HP "; THRHP; " PROPELLOR EFF "; EFF
5135 LPRINT "FUSELAGE ADDED DRAG "; DELDRG; " THRUST MINUS THIS LOSS "; THRNET; " LBS"
5140 LPRINT "JET HORSEPOWER "; JETTOT; " JET HP EFF "; JEFF
5145 LPRINT "PROPULSIVE SYSTEM EFF (WITH FUS. DRG) "; SEFF
5150 LPRINT
5152 LPRINT
5170 REM
5172 REM NEW RPM VALUE
5180 NEXT NR
5192 IF PCODE > .1 THEN LPRINT
5200 NEXT NS: REM NEXT PLANE SPEED
5210 IF PCODE > .1 THEN LPRINT
6000 END
PROGRAM PRPLRITF - FOR THRUST AND POWER AT DESIGNATED SPEEDS AND RPM
12-26-1999 00:48:29
CASE paul2 - ALTITUDE 0 FT - DENSITY 2.37689E-03
PROP DIA 72 IN PITCH 50 IN
RPM 0
BLADE WIDTH @ .9R 2 .7R 3 .5R 4 .3R 5
FUSELAGE AREA 8 DRAG COEFF .2
RADIUS WIDTH ANGLE HP ZONE LIFT THRST ANG ATT PITCH VEL
0.30 5.00 36.38 -13.32 -29.07 -11.38 254.48
0.50 4.00 23.85 -17.69 -38.82 -9.80 424.13
0.70 3.00 17.52 -15.30 -35.25 -8.22 593.78
PLANE SPEED 200 MPH RPM 2700
PITCH AT THIS POINT 50 INCHES
APPROX AIR VEL OVER TIP 719.2122 FT/SEC
TOTAL THRUST -103.1496 HORSEPOWER REQUIRED -46.30967
THRUST HP -55.0131 PROPELLOR EFF 1.18794
FUSELAGE ADDED DRAG -10.46211 THRUST MINUS THIS LOSS -92.68745 LBS
JET HORSEPOWER -53.10076 JET HP EFF 1.146645
PROPULSIVE SYSTEM EFF (WITH FUS. DRG) 1.067451
RADIUS WIDTH ANGLE HP ZONE LIFT THRST ANG ATT PITCH VEL
0.30 5.00 36.38 -12.12 -26.34 -10.45 263.90
0.50 4.00 23.85 -15.31 -34.01 -8.94 439.84
0.70 3.00 17.52 -12.25 -29.27 -7.49 615.77
PLANE SPEED 200 MPH RPM 2800
PITCH AT THIS POINT 50 INCHES
APPROX AIR VEL OVER TIP 742.078 FT/SEC
TOTAL THRUST -89.62291 HORSEPOWER REQUIRED -39.67544
THRUST HP -47.79889 PROPELLOR EFF 1.204747
FUSELAGE ADDED DRAG -9.38092 THRUST MINUS THIS LOSS -80.24199 LBS
JET HORSEPOWER -46.28648 JET HP EFF 1.166628
PROPULSIVE SYSTEM EFF (WITH FUS. DRG) 1.078645
RADIUS WIDTH ANGLE HP ZONE LIFT THRST ANG ATT PITCH VEL
0.30 5.00 36.38 -10.71 -23.31 -9.55 273.33
0.50 4.00 23.85 -13.16 -29.61 -8.21 455.55
0.70 3.00 17.52 -8.92 -22.78 -6.80 637.77
PLANE SPEED 200 MPH RPM 2900
PITCH AT THIS POINT 50 INCHES
APPROX AIR VEL OVER TIP 765.0422 FT/SEC
TOTAL THRUST -75.69915 HORSEPOWER REQUIRED -32.7887
THRUST HP -40.37288 PROPELLOR EFF 1.231305
FUSELAGE ADDED DRAG -7.933426 THRUST MINUS THIS LOSS -67.76572 LBS
JET HORSEPOWER -39.26896 JET HP EFF 1.197637
PROPULSIVE SYSTEM EFF (WITH FUS. DRG) 1.102262
RADIUS WIDTH ANGLE HP ZONE LIFT THRST ANG ATT PITCH VEL
0.30 5.00 36.38 -9.39 -20.53 -8.78 282.75
0.50 4.00 23.85 -10.32 -23.96 -7.43 471.26
0.70 3.00 17.52 -5.32 -15.79 -6.15 659.76
PLANE SPEED 200 MPH RPM 3000
PITCH AT THIS POINT 50 INCHES
APPROX AIR VEL OVER TIP 788.0963 FT/SEC
TOTAL THRUST -60.27187 HORSEPOWER REQUIRED -25.02871
THRUST HP -32.145 PROPELLOR EFF 1.284325
FUSELAGE ADDED DRAG -6.624878 THRUST MINUS THIS LOSS -53.64699 LBS
JET HORSEPOWER -31.38937 JET HP EFF 1.254135
PROPULSIVE SYSTEM EFF (WITH FUS. DRG) 1.143156
RADIUS WIDTH ANGLE HP ZONE LIFT THRST ANG ATT PITCH VEL
0.30 5.00 36.38 -7.61 -16.93 -7.94 292.18
0.50 4.00 23.85 -7.72 -18.78 -6.78 486.96
0.70 3.00 17.52 -1.94 -9.27 -5.61 681.75
PLANE SPEED 200 MPH RPM 3100
PITCH AT THIS POINT 50 INCHES
APPROX AIR VEL OVER TIP 811.5908 FT/SEC
TOTAL THRUST -44.97798 HORSEPOWER REQUIRED -17.27905
THRUST HP -23.98826 PROPELLOR EFF 1.388286
FUSELAGE ADDED DRAG -4.65181 THRUST MINUS THIS LOSS -40.32617 LBS
JET HORSEPOWER -23.53758 JET HP EFF 1.362204
PROPULSIVE SYSTEM EFF (WITH FUS. DRG) 1.244704
RADIUS WIDTH ANGLE HP ZONE LIFT THRST ANG ATT PITCH VEL
0.30 5.00 36.38 -6.01 -13.67 -7.23 301.60
0.50 4.00 23.85 -4.42 -12.29 -6.07 502.67
0.70 3.00 17.52 2.21 -1.28 -5.03 703.74
PLANE SPEED 200 MPH RPM 3200
PITCH AT THIS POINT 50 INCHES
APPROX AIR VEL OVER TIP 834.7933 FT/SEC
TOTAL THRUST -27.24472 HORSEPOWER REQUIRED -8.224088
THRUST HP -14.53052 PROPELLOR EFF 1.766824
FUSELAGE ADDED DRAG -3.329544 THRUST MINUS THIS LOSS -23.91518 LBS
JET HORSEPOWER -14.28963 JET HP EFF 1.737534
PROPULSIVE SYSTEM EFF (WITH FUS. DRG) 1.550903
RADIUS WIDTH ANGLE HP ZONE LIFT THRST ANG ATT PITCH VEL
0.30 5.00 36.38 -3.95 -9.57 -6.45 311.03
0.50 4.00 23.85 -1.36 -6.32 -5.49 518.38
0.70 3.00 17.52 6.61 6.02 -4.55 725.73
PLANE SPEED 200 MPH RPM 3300
PITCH AT THIS POINT 50 INCHES
APPROX AIR VEL OVER TIP 858.4079 FT/SEC
TOTAL THRUST -9.870762 HORSEPOWER REQUIRED 1.306951
THRUST HP -5.264407 PROPELLOR EFF -4.028008
FUSELAGE ADDED DRAG -1.335953 THRUST MINUS THIS LOSS -8.534809 LBS
JET HORSEPOWER -5.143505 JET HP EFF -3.935501
PROPULSIVE SYSTEM EFF (WITH FUS. DRG) -3.482839
RADIUS WIDTH ANGLE HP ZONE LIFT THRST ANG ATT PITCH VEL
0.30 5.00 36.38 -2.07 -5.83 -5.79 320.45
0.50 4.00 23.85 2.52 0.95 -4.84 534.09
0.70 3.00 17.52 11.98 14.82 -4.03 747.72
PLANE SPEED 200 MPH RPM 3400
PITCH AT THIS POINT 50 INCHES
APPROX AIR VEL OVER TIP 881.7363 FT/SEC
TOTAL THRUST 9.943686 HORSEPOWER REQUIRED 12.43405
THRUST HP 5.303299 PROPELLOR EFF .4265143
FUSELAGE ADDED DRAG 0 THRUST MINUS THIS LOSS 9.943686 LBS
JET HORSEPOWER 5.387269 JET HP EFF .4332675
PROPULSIVE SYSTEM EFF (WITH FUS. DRG) .4265143
RADIUS WIDTH ANGLE HP ZONE LIFT THRST ANG ATT PITCH VEL
0.30 5.00 36.38 -0.04 -1.87 -5.16 329.88
0.50 4.00 23.85 6.41 7.52 -4.31 549.80
0.70 3.00 17.52 17.12 23.04 -3.60 769.72
PLANE SPEED 200 MPH RPM 3500
PITCH AT THIS POINT 50 INCHES
APPROX AIR VEL OVER TIP 905.4521 FT/SEC
TOTAL THRUST 28.69271 HORSEPOWER REQUIRED 23.49175
THRUST HP 15.30278 PROPELLOR EFF .6514109
FUSELAGE ADDED DRAG 2.238708 THRUST MINUS THIS LOSS 26.45401 LBS
JET HORSEPOWER 15.4874 JET HP EFF .6592699
PROPULSIVE SYSTEM EFF (WITH FUS. DRG) .6005855
RADIUS WIDTH ANGLE HP ZONE LIFT THRST ANG ATT PITCH VEL
0.30 5.00 36.38 2.59 2.84 -4.46 339.30
0.50 4.00 23.85 10.58 14.46 -3.81 565.51
0.70 3.00 17.52 23.21 32.83 -3.12 791.71
PLANE SPEED 200 MPH RPM 3600
PITCH AT THIS POINT 50 INCHES
APPROX AIR VEL OVER TIP 928.8879 FT/SEC
TOTAL THRUST 50.13834 HORSEPOWER REQUIRED 36.38413
THRUST HP 26.74045 PROPELLOR EFF .734948
FUSELAGE ADDED DRAG 3.739655 THRUST MINUS THIS LOSS 46.39868 LBS
JET HORSEPOWER 27.11784 JET HP EFF .7453205
PROPULSIVE SYSTEM EFF (WITH FUS. DRG) .6801307
RADIUS WIDTH ANGLE HP ZONE LIFT THRST ANG ATT PITCH VEL
0.30 5.00 36.38 5.07 7.09 -3.88 348.73
0.50 4.00 23.85 15.04 21.79 -3.32 581.21
0.70 3.00 17.52 29.07 41.98 -2.73 813.70
PLANE SPEED 200 MPH RPM 3700
PITCH AT THIS POINT 50 INCHES
APPROX AIR VEL OVER TIP 952.6897 FT/SEC
TOTAL THRUST 70.86523 HORSEPOWER REQUIRED 49.1814
THRUST HP 37.79479 PROPELLOR EFF .7684774
FUSELAGE ADDED DRAG 6.003708 THRUST MINUS THIS LOSS 64.86153 LBS
JET HORSEPOWER 38.55299 JET HP EFF .7838938
PROPULSIVE SYSTEM EFF (WITH FUS. DRG) .7033719
RADIUS WIDTH ANGLE HP ZONE LIFT THRST ANG ATT PITCH VEL
0.30 5.00 36.38 7.72 11.58 -3.32 358.15
0.50 4.00 23.85 19.79 29.49 -2.86 596.92
0.70 3.00 17.52 35.30 51.58 -2.36 835.69
PLANE SPEED 200 MPH RPM 3800
PITCH AT THIS POINT 50 INCHES
APPROX AIR VEL OVER TIP 976.5269 FT/SEC
TOTAL THRUST 92.65105 HORSEPOWER REQUIRED 62.80588
THRUST HP 49.41389 PROPELLOR EFF .7867718
FUSELAGE ADDED DRAG 8.283005 THRUST MINUS THIS LOSS 84.36804 LBS
JET HORSEPOWER 50.71749 JET HP EFF .8075278
PROPULSIVE SYSTEM EFF (WITH FUS. DRG) .7164344
RADIUS WIDTH ANGLE HP ZONE LIFT THRST ANG ATT PITCH VEL
0.30 5.00 36.38 10.53 16.30 -2.77 367.58
0.50 4.00 23.85 24.83 37.57 -2.42 612.63
0.70 3.00 17.52 42.52 62.86 -1.95 857.68
PLANE SPEED 200 MPH RPM 3900
PITCH AT THIS POINT 50 INCHES
APPROX AIR VEL OVER TIP 1000.093 FT/SEC
TOTAL THRUST 116.7227 HORSEPOWER REQUIRED 77.88644
THRUST HP 62.25211 PROPELLOR EFF .7992675
FUSELAGE ADDED DRAG 10.04074 THRUST MINUS THIS LOSS 106.682 LBS
JET HORSEPOWER 64.18751 JET HP EFF .8241165
PROPULSIVE SYSTEM EFF (WITH FUS. DRG) .7305128
RADIUS WIDTH ANGLE HP ZONE LIFT THRST ANG ATT PITCH VEL
0.30 5.00 36.38 13.52 21.24 -2.25 377.00
0.50 4.00 23.85 30.18 46.03 -1.99 628.34
0.70 3.00 17.52 49.52 73.39 -1.62 879.68
PLANE SPEED 200 MPH RPM 4000
PITCH AT THIS POINT 50 INCHES
APPROX AIR VEL OVER TIP 1023.999 FT/SEC
TOTAL THRUST 140.6621 HORSEPOWER REQUIRED 93.21758
THRUST HP 75.01981 PROPELLOR EFF .8047818
FUSELAGE ADDED DRAG 12.34689 THRUST MINUS THIS LOSS 128.3152 LBS
JET HORSEPOWER 77.8506 JET HP EFF .8351494
PROPULSIVE SYSTEM EFF (WITH FUS. DRG) .7341405
