This is my latest program. Still a bug in there somewhere.
The net thrust HP does not correlate with the calculated
HP given the torque and RPM. The thrust seems too high
for one blade at a lift coef. of only .5.

I am going to start with the spread sheet Bob White did and
convert it to spread sheet form. More people can deal with
spread sheets than they can deal with Quick BASIC.
Also QB is limited to 80 characters wide which is
a problem if you want a lot of debugging columns.
IMHO it is still faster than doing a spread sheet however.
I would love to have a version of QB (NOT VB!!!!) that
would handle 132 or more characters wide.

RPM = 2700    MPH = 200    Lift Coef. = .5    Drag Coef. = .01
Air density = .0026

Radius     Tang Vel  Angle    Cord Vel   Cord   Seg Area   Seg Thrust Seg Torq
Inch       MPH       Degree   MPH        Inch   Sq. feet   Pound      Pound
   3.00     48.2     76.5      206       7.20        0.15      8.5     0.04
   6.00     96.3     64.3      222       6.60        0.14      9.8     0.09
   9.00    144.5     54.1      247       6.00        0.13     12.2     0.15
  12.00    192.7     46.1      278       5.40        0.11     15.7     0.23
  15.00    240.9     39.7      313       4.80        0.10     19.9     0.32
  18.00    289.0     34.7      351       4.20        0.09     24.7     0.42
  21.00    337.2     30.7      392       3.60        0.08     29.4     0.52
  24.00    385.4     27.4      434       3.00        0.06     33.3     0.61
  27.00    433.5     24.8      477       2.40        0.05     35.4     0.67
  30.00    481.7     22.5      522       2.40        0.05     46.1     0.88
  33.00    529.9     20.7      566       1.80        0.04     44.3     0.86
  36.00    578.0     19.1      612       1.20        0.03     37.2     0.73

Total Thrust Lb = 316     Thrust HP = 169      AvgCord Ft =  0.34
Induced Drag Lb =  4.24   Torque Due to Seg. Drag Ft/Lb =  5.52
Total Torque Ft/Lb = 18.3 Calculated HP =  9.4


'Pitch20D.BAS

OPEN "pitch200.dat" FOR OUTPUT AS #1
CLS

DIM Cord(25)

Thrust = 0: Torque = 0: TotArea = 0: TotCord = 0
AirDen = .0026: MPH = 200: CsubL = .5: CsubD = .01: RPM = 2700
PRINT #1, "RPM ="; RPM;
PRINT #1, "   MPH ="; MPH;
PRINT #1, "   Lift Coef. ="; CsubL;
PRINT #1, "   Drag Coef. ="; CsubD
PRINT #1, "Air density ="; AirDen
PRINT #1,


PRINT #1, "Radius     Tang Vel  Angle    Cord Vel   Cord   Seg Area   Seg Thrust Seg Torq"
PRINT #1, "Inch       MPH       Degree   MPH        Inch   Sq. feet   Pound      Pound"

FOR Radius = .25 TO 3 STEP .25   'in feet
RadiusInch = Radius * 12         'convert to inches
PRINT #1, USING "###.##"; RadiusInch;

TangVelFPS = (6.28 * Radius * RPM) / 60  'calc tang vel in FPS

TangVelMPH = (TangVelFPS * 60) / 88      'convert to MPH
PRINT #1, USING "#######.#"; TangVelMPH;

'Tan(a) = opp/adj
tan1 = MPH / TangVelMPH         'calc the ratio

angleRAD = ATN(tan1)            'calc the angle in radians
AngleDeg = (angleRAD * 57.295)  'convert to degrees
PRINT #1, USING "#######.#"; AngleDeg;

CordVel = (TangVelMPH ^ 2 + MPH ^ 2) ^ .5
PRINT #1, USING "#########"; CordVel;

READ Cord  'in feet
PRINT #1, USING "########.##"; Cord * 12; 'convert to inches

TotCord = TotCord + Cord  'add up all cords

SegArea = .25 * Cord   '.25 feet or 3 inches times the cord in feet
PRINT #1, USING "#########.##"; SegArea;

TotArea = TotArea + SegArea

LiftInc = SegArea * (CordVel) ^ 2 * AirDen * CsubL

Angle2Deg = 90 - AngleDeg           'calc horz component
Angle2RAD = Angle2Deg / 57.295

'tan(a)=opp/adj   adj = opp/tan(a)
'cos(a)=adj/hyp   adj = cos(a)/hyp

ThrustInc = LiftInc / COS(Angle2RAD)
PRINT #1, USING "#######.#"; ThrustInc;

Thrust = Thrust + ThrustInc          'add them up

'drag = area times  V^2 times  Air density times Cd in pounds

DragInc = SegArea * (CordVel) ^ 2 * AirDen * CsubD
TorqueInc = DragInc * Radius         'Radius is in feet
PRINT #1, USING "######.##"; TorqueInc
Torque = Torque + TorqueInc         'add them up

NEXT

'arbritrary cord lengths in feet
DATA  .6,.55,.5,.45,.4, .35, .3, .25, .2,.2,.15,.1

'from here on... done only one time
PRINT #1,
PRINT #1, "Total Thrust Lb =";
PRINT #1, USING "####"; Thrust;

'calculate the net thrust HP

FPS = MPH * 88 / 60
PRINT #1, "     Thrust HP =";
PRINT #1, USING "####"; (Thrust * FPS) / 550;

'figure out the average cord

AvgCord = TotCord / 12   '12 steps AvgCord is in feet

PRINT #1, "      AvgCord Ft =";
PRINT #1, USING "###.##"; AvgCord
AspectRat = 3 / AvgCord   'divide blade lenght by Avg cord

'InducedDrag = Cl^2/Pi*A

InducedDrag = (CsubL ^ 2 / (3.1416 * AspectRat)) / 2

PRINT #1, "Induced Drag Lb =";
PRINT #1, USING "###.##"; InducedDrag;


PRINT #1, "   Torque Due to Seg. Drag Lb =";
PRINT #1, USING "###.##"; Torque


TotTorque = Torque + (InducedDrag * 3)

PRINT #1, "Total Torque Ft/Lb =";
PRINT #1, USING "###.#"; TotTorque;

CalcHP = TotTorque * 2700 / 5250

PRINT #1, " Calculated HP =";
PRINT #1, USING "###.#"; CalcHP



CLOSE

SHELL "more < pitch200.dat"
SYSTEM


Paul Lamar ...No rotor no motor.

The Rotary Engine NewsLetter. Powered by Linux.
ACRE NL web site. http://www.rotaryeng.net
Copyright 1998-2006 All world wide rights reserved.

Hi Paul,

I took your current formula and updated the spreadsheet.  I've also
rearranged it and separated all of intermediate calculations.

I ran into a problem when I got to the induced drag calculation.  I get
a value of .0045.  If I do an estimate based on your formula, I get:

AspectRat = 3 / AvgCord
          =3 / .34  is approximately 9
(My Avg Cord agrees with yours)

Now,
InducedDrag = (CsubL ^ 2 / (3.1416 * AspectRat)) / 2
            = (.5 * .5 / (3 * 9)) / 2
            = (.25 / 27) / 2  is approximately .005

Yet your program calculated 4.24, and I cannot see what I'm doing
differently.  Once that is fixed, the total torque and HP will agree.

Outside of that, this version should be easier to update and modify.

Bob W.